版主能否提供神泣辅助软件脚本代码

ourzn

版主能否提供神泣辅助软件脚本代码

版主能否提供辅助软件脚本代码～～神泣的  （功能上可以改进 加入状态等等）

让大家能根据自己讲需要修改脚本～

ourzn

以下是我找到～

UserVar GetYN=1 捡物(1捡，0不捡)
UserVar SitDwonYN=1 打坐(1坐，0不坐)
UserVar SitDown_MP1=0 蓝少也打坐(1是，0否)
UserVar SitDown_MP2=0 黄少也打坐(1是，0否)
UserVar Count_Skill=3 攻击技能使用个数
UserVar Count_State=2 状态技能使用个数
VBS Dim Time_skill(9)
UserVar Time_skill(2)=6 攻击技能1冷却(秒)
UserVar Time_skill(3)=6 攻击技能2冷却(秒)
UserVar Time_skill(4)=6 攻击技能3冷却(秒)
UserVar Time_skill(5)=6 攻击技能4冷却(秒)
UserVar Time_skill(6)=6 攻击技能5冷却(秒)
UserVar Time_skill(0)=300 状态技能1冷却(秒)
UserVar Time_skill(9)=300 状态技能2冷却(秒)
UserVar Time_skill(8)=300 状态技能3冷却(秒)
UserVar Time_skill(7)=600 状态技能4冷却(秒)
//--------------------------------------------------------
//1024*768 全屏 16位色
x_HP=110
y_HP=44
color_HP="390CAD"
x_MP1=114
y_MP1=62
color_MP1="D6A200"
x_MP2=118
y_MP2=82
color_MP2="008ABD"
x_ET=250
y_ET=36
color_ET="4218A5"
//--------------------------------------------------------
TIMESKILL=1
//技能类型，涉及到冷却。
LESSHALF=92
LESS=90
//状态描述。
NONE=0
//状态描述
NORMAL=91
//状态描述。
SkillType=99
//技能类型，分为TIMESKILL、NORMAL两种
//99仅为标识初始化。
SkillNum=99
//技能编号。99仅为标识初始化。
VBS Dim Time(9,2)
//记录时间的起止，用于技能。
//*初始化数组time
VBS time0=timer
n=0
For 10
    time(n,0)=time0-Time_skill(n)
    n=n+1
EndFor
//-----------------------------------------------------------
//*进入循环打怪前，释放状态技能一次
SkillType=TIMESKILL
SkillNum=0
Gosub Skill
n=9
For Count_State-1
    SkillNum=n
    Gosub Skill
    n=n-1
EndFor
//-----------------------------------------------------------
//*循环杀怪
While 1
    Gosub CheckETHP
    If ETHP=NONE
        //怪已死,则
        //*释放状态技能。
        SkillType=TIMESKILL
        SkillNum=0
        Gosub Skill
        n=9
        For Count_State-1
            SkillNum=n
            Gosub Skill
            n=n-1
        EndFor
        //*打坐
        If SitDwonYN=1
            Gosub CheckHP
            Gosub CheckMP1
            Gosub CheckMP2
            If (HP<>NORMAL) or (MP1=LESS and SitDown_MP1=1) or (MP2=LESS and SitDown_MP2=1)
                Gosub TakeRest
            EndIf
        EndIf
        //*拾物
        If GetYN=1 and LockET=1
            Gosub GetGoods
        EndIf
        //*寻下一个怪。
        KeyPress 84 1
        Delay 150
        LockET=0
    Else
        LockET=1
        //*普通攻击
        SkillType=NORMAL
        Gosub Skill
        //*使用连续技能。
        Gosub CheckMP2
        If MP2=NORMAL
            SkillType=TIMESKILL
            n=2
            For Count_Skill
                Gosub CheckETHP
                If ETHP=NORMAL
                    SkillNum=n
                    Gosub Skill
                    Delay 1200
                Else
                    Goto BREAK
                EndIf
                n=n+1
            EndFor
            Rem BREAK
        EndIf
        //--------------------------------------
        LockET=1
    EndIf
EndWhile
EndScript
//*技能
Sub Skill
    //*补红
    Gosub CheckHP
    If HP=LESS
        KeyPress 97 1
        Delay 200
    EndIf
    //*补黄
    Gosub CheckMP2
    If MP2=LESS
        KeyPress 99 1
        Delay 200
    EndIf
    //*补蓝
    Gosub CheckMP1
    If MP1=LESS
        KeyPress 98 1
        Delay 200
    EndIf
    //--------------------------------------
    If SkillType=NORMAL
        //*普通攻击
        KeyPress 84 1
        Delay 300
    ElseIf SkillType=TIMESKILL
        VBS time(SkillNum,1)=timer
        TimePast=time(SkillNum,1)-Time(SkillNum,0)
        timex=Time_skill(SkillNum)
        If TimePast>timex
            If SkillNum>(10-Count_State) or SkillNum=0
                Delay 1100
            Else
                Delay 300
            EndIf
            KeyPress 48+SkillNum 3
            Delay 300
            Time(SkillNum,0)=Time(SkillNum,1)
        ElseIf TimePast<0
            Time(SkillNum,0)=Time(SkillNum,1)
        EndIf
    EndIf
Return
//*血
Sub CheckHP
    IfColor x_HP y_HP 390CAD 1
        HP=LESS
    Else
        VBSCall FindColor(115,47,166,47,"FFFFFF",x_white,y_white)
        IfColor x_white+4 46 3908C6 1
            HP=LESSHALF
        Else
            HP=NORMAL
        EndIf
    EndIf
Return
//*蓝
Sub CheckMP1
    IfColor x_MP1 y_MP1 D6A200 1
        MP1=LESS
    Else
        MP1=NORMAL
    EndIf
Return
//*黄
Sub CheckMP2
    IfColor x_MP2 y_MP2 008ABD 1
        MP2=LESS
    Else
        MP2=NORMAL
    EndIf
Return
//*怪血
Sub CheckETHP
    IfColor x_ET y_ET 4218A5 1
        ETHP=NONE
    Else
        ETHP=NORMAL
    EndIf
Return
//*捡物
Sub GetGoods
    KeyPress 90 1
    Delay 500
    KeyPress 90 1
    Delay 500
Return
//*打坐
Sub TakeRest
    Delay 2000
    KeyPress 114 1
    Delay 1500
    KeyPress 88 1
    Delay 1000
    x=251
    y=38
    x1=379
    x_HPmax=x
    While 1
        IfColor x y 390CAD 2
            If x>x1
                IfColor 199 62 D6A200 0
                    IfColor 199 82 8ABD 0
                        KeyPress 88 1
                        Delay 1000
                        Goto break1
                    EndIf
                EndIf
            Else
                x_HPmax=x
                x=x+1
            EndIf
        EndIf
        IfColor x_HPmax y 390CAD 2
        Else
            //受攻击
            Goto break1
        EndIf
    EndWhile
    Rem break1
Return

ourzn

<神泣>祭司自动加血脚本


使用前请先参照说明设置:


QUOTE:
[ 脚本说明 ]

1.游戏分辨率1024*768/32色
2.自定义加血百分比  默认为80%
3.自定义加血技能键位  默认为数字"1"
4.脚本自动判断组队人数   如果人数有变化须重新启动脚本




[Copy to clipboard]CODE:
//---------------------------------------------- [ 声明变量 ]
dim hp,k,rs,x,y,ay,hpx,hpy,key
//---------------------------------------------- [ 用户自定义变量 ]
UserVar hp=80 设置自动补红的百分比(默认为80%)
UserVar k=1 设置自动补红技能键位(默认为数字1)
hp=cint(hp):k=asc(k):rs=0
//---------------------------------------------- [ 血条定位 ]
Delay 100
VBSCall FindColorex(10,90,210,400,"32089C",0,0.9,x,y)
//区域找组队血条颜色
If x>=10 and y>=90
    IfColor x y+9 D6A506 2
        //如果血条下面的蓝条存在
        hpx=x+cint((119/100)*hp):ay=y
        //计算组队血条自定义百分比位置
        Gosub 组队人数
    Else
        MessageBox 没有找到队伍血条
        Goto end
    EndIf
EndIf
//---------------------------------------------- [ 自动加血 ]
Rem start
key=112:hpy=ay
//定义选取队员键码和血条纵坐标变量
For rs
    Delay 50
    IfColor hpx hpy 000000 0
        //如果血条百分比位置为底色,则执行以下的加血命令
        Delay 50
        KeyDownH key 1
        Delay 100
        KeyUpH key 1
        Delay 200
        KeyDownH k 1
        Delay 200
        KeyUpH k 1
    EndIf
    key=key+1:hpy=hpy+52
    //变量递增
EndFor
Delay 50
Goto start
//---------------------------------------------- [ 判断组队人数 ]
Sub 组队人数
    For 7
        Delay 10
        IfColor x y 32089C 2
            rs=rs+1
            //计算组队人数
        EndIf
        y=y+52
    EndFor
Return 组队人数
//---------------------------------------------- [ 脚本终止 ]
Rem end
EndScript

SzAngel

神泣的NP反挂系统把按键精灵盯的死死的,,,在神泣里按键精灵实在没发展前途!

ourzn

我的神泣np版本从915自己变成905了倒退了~~~
版主能提供不?
我主要想获得障碍物处理部分~~